NetPacket::UDP(3)

NAME
NetPacket::UDP - Assemble and disassemble UDP (User Datagram Protocol) packets.

VERSION
version 1.7.2

SYNOPSIS
  use NetPacket::UDP;

  $udp_obj = NetPacket::UDP->decode($raw_pkt);
  $udp_pkt = $udp_obj->encode($l3_obj);
  $udp_data = NetPacket::UDP::strip($raw_pkt);

DESCRIPTION
"NetPacket::UDP" provides a set of routines for assembling and disassembling packets using UDP (User Datagram Protocol).

  Methods

"NetPacket::UDP->decode([RAW PACKET])"
    Decode the raw packet data given and return an object containing instance data. This method will quite happily decode garbage input. It is the responsibility of the programmer to ensure valid packet data is passed to this method.

"$udp_packet-<gt"encode($l3_obj)>
    Return the encoded version of the UDP packet object. Needs part of the IP header contained (src_ip and dest_ip specifically) in $l3_obj, in order to calculate the UDP checksum. The length field will also be set automatically based on values provided.

  Functions

"NetPacket::UDP::strip([RAW PACKET])"
    Return the encapsulated data (or payload) contained in the UDP packet. This data is suitable to be used as input for other "NetPacket::*" modules.

    This function is equivalent to creating an object using the "decode()" constructor and returning the "data" field of that object.

  Instance data
The instance data for the "NetPacket::UDP" object consists of the following fields.

src_port
    The source UDP port for the datagram.

dest_port
    The destination UDP port for the datagram.

len The length (including length of header) in bytes for this packet.

cksum
    The checksum value for this packet.

data
    The encapsulated data (payload) for this packet.

  IP data
The IP data for the $l3_obj object consists of the following fields. Additional items may be supplied as well as passing the whole object returned by NetPacket::IP->decode but are unnecessary.

src_ip
    The source IP for the datagram

dest_ip
    The destination IP for the datagram

  Exports

default
    none

exportable
    udp_strip

tags
    The following tags group together related exportable items.

    ":strip"
        Import the strip function "udp_strip".

    ":ALL"
        All the above exportable items.

EXAMPLE
The following example prints the source IP address and port, the destination IP address and port, and the UDP packet length:

  #!/usr/bin/perl -w

  use strict;
  use Net::PcapUtils;
  use NetPacket::Ethernet qw(:strip);
  use NetPacket::IP;
  use NetPacket::UDP;

  sub process_pkt {
      my($arg, $hdr, $pkt) = @_;

      my $ip_obj = NetPacket::IP->decode(eth_strip($pkt));
      my $udp_obj = NetPacket::UDP->decode($ip_obj->{data});

      print("$ip_obj->{src_ip}:$udp_obj->{src_port} -> ",
            "$ip_obj->{dest_ip}:$udp_obj->{dest_port} ",
            "$udp_obj->{len}\n");
  }

  Net::PcapUtils::loop(\&process_pkt, FILTER => 'udp');

The following is an example use in combination with Net::Divert to alter the payload of packets that pass through. All occurrences of foo will be replaced with bar. This example is easy to test with netcat, but otherwise makes little sense. :) Adapt to your needs:

    use Net::Divert;
    use NetPacket::IP qw(IP_PROTO_UDP);
    use NetPacket::UDP;

    $divobj = Net::Divert->new('yourhost',9999);

    $divobj->getPackets(\&alterPacket);

    sub alterPacket
    {
        my ($data, $fwtag) = @_;

        $ip_obj = NetPacket::IP->decode($data);

        if($ip_obj->{proto} == IP_PROTO_UDP) {

            # decode the UDP header
            $udp_obj = NetPacket::UDP->decode($ip_obj->{data});

            # replace foo in the payload with bar
            $udp_obj->{data} =~ s/foo/bar/g;

            # re-encode the packet
            $ip_obj->{data} = $udp_obj->encode($udp_obj, $ip_obj);
            $data = $ip_obj->encode;

        }

        $divobj->putPacket($data,$fwtag);
    }

COPYRIGHT
Copyright (c) 2001 Tim Potter.

Copyright (c) 1995,1996,1997,1998,1999 ANU and CSIRO on behalf of the participants in the CRC for Advanced Computational Systems ('ACSys').

This module is free software. You can redistribute it and/or modify it under the terms of the Artistic License 2.0.

This program is distributed in the hope that it will be useful, but without any warranty; without even the implied warranty of merchantability or fitness for a particular purpose.

AUTHOR
Tim Potter <tpot@samba.org>

Stephanie Wehner <atrak@itsx.com>

Yanick Champoux <yanick@cpan.org>